dnl Process this file with autoconf to create configure.

dnl ################################################################
dnl # Initialize autoconf
dnl ################################################################
AC_INIT(libsexymm, 0.1.9, chipx86@chipx86.com)
AC_PREREQ(2.50)
AC_CONFIG_SRCDIR(config.h.in)
AC_COPYRIGHT([Copyright 2005-2006 Christian Hammond])


dnl ################################################################
dnl # Version information
dnl ################################################################
LIBSEXYMM_MAJOR_VERSION=0
LIBSEXYMM_MINOR_VERSION=1
LIBSEXYMM_MICRO_VERSION=9
LIBSEXYMM_DEVEL_VERSION=0

LIBSEXYMM_VERSION=$LIBSEXYMM_MAJOR_VERSION.$LIBSEXYMM_MINOR_VERSION.$LIBSEXYMM_MICRO_VERSION

if test "x$LIBSEXYMM_DEVEL_VERSION" != "x0"; then
	LIBSEXYMM_VERSION=$LIBSEXYMM_VERSION.$LIBSEXYMM_DEVEL_VERSION
fi

AC_DEFINE_UNQUOTED(LIBSEXYMM_MAJOR_VERSION, $LIBSEXYMM_MAJOR_VERSION,
	[libsexy major version.])
AC_DEFINE_UNQUOTED(LIBSEXYMM_MINOR_VERSION, $LIBSEXYMM_MINOR_VERSION,
	[libsexy minor version.])
AC_DEFINE_UNQUOTED(LIBSEXYMM_MICRO_VERSION, $LIBSEXYMM_MICRO_VERSION,
	[libsexy micro version.])
AC_DEFINE_UNQUOTED(LIBSEXYMM_VERSION, "$LIBSEXYMM_VERSION",
	[libsexy version.])

dnl ################################################################
dnl # libtool versioning
dnl ################################################################
dnl #
dnl # +1 :  0 : +1   == new interface that does not break old one.
dnl # +1 :  0 :  0   == removed an interface. Breaks old apps.
dnl #  ? : +1 :  ?   == internal changes that doesn't break anything.
dnl #
dnl # CURRENT : REVISION : AGE
dnl #
LT_CURRENT=2
LT_REVISION=1
LT_AGE=0

LT_RELEASE=$LIBSEXYMM_MAJOR_VERSION.$LIBSEXYMM_MINOR_VERSION.$LIBSEXYMM_MICRO_VERSION

AC_SUBST(LT_RELEASE)
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)

dnl ################################################################
dnl # Initialize automake
dnl ################################################################
VERSION=$LIBSEXYMM_VERSION
PACKAGE=libsexymm

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

dnl ################################################################
dnl # Specify a header configuration file
dnl ################################################################
AM_CONFIG_HEADER(config.h libsexy/libsexymmconfig.h)

AM_MAINTAINER_MODE

dnl ################################################################
dnl # Check for some standard stuff.
dnl ################################################################
AC_PROG_CC
#AC_ARG_PROGRAM
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_PROG_LN_S
AC_PROG_INSTALL

AC_C_CONST
AC_TYPE_SIZE_T
AC_EXEEXT

AM_PROG_LIBTOOL

GLIBMM_PREFIX=`pkg-config --variable=prefix glibmm-2.4`
GMM_PROCDIR=$GLIBMM_PREFIX/lib/glibmm-2.4/proc
AC_SUBST(GMM_PROCDIR)
GMM_PROC=$GMM_PROCDIR/gmmproc
AC_SUBST(GMM_PROC)

GTKMM_VERSION_NEEDED=2.4.0
AC_SUBST(GTKMM_VERSION_NEEDED)
SEXY_VERSION_NEEDED=0.1.9
AC_SUBST(SEXY_VERSION_NEEDED)

PKG_CHECK_MODULES(LIBSEXYMM, gtkmm-2.4 >= $GTKMM_VERSION_NEEDED libsexy >= $SEXY_VERSION_NEEDED)
AC_SUBST(LIBSEXYMM_CFLAGS)
AC_SUBST(LIBSEXYMM_LIBS)

# Create a list of input directories for Doxygen.  We have to check wether
# we are building in the source directory, because Doxygen doesn't like
# duplicated directories in the input list.
LIBSEXYMM_DOXYGEN_INPUT=''
gtkmm_srcdir=`cd "$srcdir" && pwd`
gtkmm_builddir=`pwd`
for sublib in libsexy
do
	LIBSEXYMM_DOXYGEN_INPUT="$LIBSEXYMM_DOXYGEN_INPUT $gtkmm_builddir/$sublib/$sublib""mm/"
	test "x$gtkmm_builddir" = "x$gtkmm_srcdir" || \
	LIBSEXYMM_DOXYGEN_INPUT="$LIBSEXYMM_DOXYGEN_INPUT $gtkmm_srcdir/$sublib/$sublib""mm/"
done
AC_SUBST(LIBSEXYMM_DOXYGEN_INPUT)


dnl # Use wall if we have GCC
if test "x$GCC" = "xyes"; then
	CFLAGS="$CFLAGS -Wall"
fi

AC_SUBST(CFLAGS)

dnl ################################################################
dnl # Output the Makefiles
dnl ################################################################
AC_CONFIG_FILES([
Makefile
libsexy/Makefile
libsexy/libsexymm.pc
libsexy/src/Makefile
libsexy/libsexymm/Makefile
libsexy/libsexymm/private/Makefile
scripts/Makefile
tests/Makefile
tools/Makefile
tools/m4/Makefile
])

AC_OUTPUT

echo
echo $PACKAGE v$VERSION

echo
echo "Now type make to compile"
echo "Then su to root and type: make install"
echo