dnl Process this file with autoconf to create configure.

dnl ################################################################
dnl # Initialize autoconf
dnl ################################################################
AC_INIT(libwebservices, 0.0.0.90, chipx86@chipx86.com)
AC_PREREQ(2.50)
AC_CONFIG_SRCDIR(config.h.in)
AC_CONFIG_MACRO_DIR([m4])
AC_COPYRIGHT([Copyright 2007 Christian Hammond])


dnl ################################################################
dnl # Version information
dnl ################################################################
LIBWEBSERVICES_MAJOR_VERSION=0
LIBWEBSERVICES_MINOR_VERSION=0
LIBWEBSERVICES_MICRO_VERSION=0
LIBWEBSERVICES_DEVEL_VERSION=90

LIBWEBSERVICES_VERSION=$LIBWEBSERVICES_MAJOR_VERSION.$LIBWEBSERVICES_MINOR_VERSION.$LIBWEBSERVICES_MICRO_VERSION

if test "x$LIBWEBSERVICES_DEVEL_VERSION" != "x0"; then
	LIBWEBSERVICES_VERSION=$LIBWEBSERVICES_VERSION.$LIBWEBSERVICES_DEVEL_VERSION
fi

AC_DEFINE_UNQUOTED(LIBWEBSERVICES_MAJOR_VERSION, $LIBWEBSERVICES_MAJOR_VERSION,
	[libwebservices major version.])
AC_DEFINE_UNQUOTED(LIBWEBSERVICES_MINOR_VERSION, $LIBWEBSERVICES_MINOR_VERSION,
	[libwebservices minor version.])
AC_DEFINE_UNQUOTED(LIBWEBSERVICES_MICRO_VERSION, $LIBWEBSERVICES_MICRO_VERSION,
	[libwebservices micro version.])
AC_DEFINE_UNQUOTED(LIBWEBSERVICES_VERSION, "$LIBWEBSERVICES_VERSION",
	[libwebservices version.])

dnl ################################################################
dnl # libtool versioning
dnl ################################################################
dnl #
dnl # +1 :  0 : +1   == new interface that does not break old one.
dnl # +1 :  0 :  0   == removed an interface. Breaks old apps.
dnl #  ? : +1 :  ?   == internal changes that doesn't break anything.
dnl #
dnl # CURRENT : REVISION : AGE
dnl #
LT_CURRENT=0
LT_REVISION=0
LT_AGE=0

LT_RELEASE=$LIBWEBSERVICES_MAJOR_VERSION.$LIBWEBSERVICES_MINOR_VERSION.$LIBWEBSERVICES_MICRO_VERSION

AC_SUBST(LT_RELEASE)
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)

dnl ################################################################
dnl # Initialize automake
dnl ################################################################
VERSION=$LIBWEBSERVICES_VERSION
PACKAGE=libwebservices

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

dnl ################################################################
dnl # Specify a header configuration file
dnl ################################################################
AM_CONFIG_HEADER(config.h)

dnl ################################################################
dnl # Check for some standard stuff.
dnl ################################################################
AC_SUBST(ACLOCAL_AMFLAGS, "$ACLOCAL_FLAGS -I m4")
AC_PROG_CC
#AC_ARG_PROGRAM
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_PROG_LN_S
AC_PROG_INSTALL

AC_C_CONST
AC_TYPE_SIZE_T
AC_EXEEXT

AM_PROG_LIBTOOL

pkg_modules="glib-2.0 >= 2.8.0, gobject-2.0 >= 2.8.0 gdk-2.0 >= 2.8.0"
PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
AC_SUBST(PACKAGES, [$pkg_modules])
AC_SUBST(PACKAGE_CFLAGS)
AC_SUBST(PACKAGE_LIBS)

dnl #
dnl # Check for Curl
dnl #
LIBCURL_CHECK_CONFIG([yes], [7.12.0], [with_curl=yes], [with_curl=no])

if test x$with_curl = xno; then
	AC_MSG_ERROR([Couldn't find a recent version of libcurl])
fi


GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
AC_SUBST(GLIB_GENMARSHAL)


dnl #
dnl # Check for Check
dnl #
AC_ARG_ENABLE([tests],
              AC_HELP_STRING([--disable-tests], [Disable the unit tests]),,
              [enable_tests=yes])

if test "x$enable_tests" = "xyes"; then
	AM_PATH_CHECK(, [have_check="yes"], [have_check="no"])
else
	have_check="no"
fi

AM_CONDITIONAL(HAVE_CHECK, test "$have_check" = "yes")


dnl ################################################################
dnl # Set up gtk-doc
dnl ################################################################
GTK_DOC_CHECK([1.4])


dnl # Use wall if we have GCC
if test "x$GCC" = "xyes"; then
	CFLAGS="$CFLAGS -Wall"
fi

AC_SUBST(CFLAGS)

dnl ################################################################
dnl # Output the Makefiles
dnl ################################################################
AC_CONFIG_FILES([
libwebservices.pc
Makefile
libwebservices/Makefile
libwebservices/common/Makefile
libwebservices/photo/Makefile
libwebservices/social/Makefile
tests/Makefile
])

AC_OUTPUT

echo
echo $PACKAGE v$VERSION

echo
echo "Now type make to compile"
echo "Then su to root and type: make install"
echo