dnl Process this file with autoconf to create configure.

dnl ################################################################
dnl # Initialize autoconf
dnl ################################################################
AC_INIT(tetringo, 0.3.1.90, chipx86@chipx86.com)
AC_PREREQ(2.50)
AC_CONFIG_SRCDIR(config.h.in)
AC_COPYRIGHT([Copyright 2006 Christian Hammond])

dnl ################################################################
dnl # Version information
dnl ################################################################
TETRINGO_MAJOR_VERSION=0
TETRINGO_MINOR_VERSION=3
TETRINGO_MICRO_VERSION=1
TETRINGO_DEVEL_VERSION=90

TETRINGO_VERSION=$TETRINGO_MAJOR_VERSION.$TETRINGO_MINOR_VERSION.$TETRINGO_MICRO_VERSION

if test "x$TETRINGO_DEVEL_VERSION" != "x0"; then
	TETRINGO_VERSION=$TETRINGO_VERSION.$TETRINGO_DEVEL_VERSION
fi

dnl ################################################################
dnl # Initialize automake
dnl ################################################################
VERSION=$TETRINGO_VERSION
PACKAGE=tetringo

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

dnl ################################################################
dnl # Specify a header configuration file
dnl ################################################################
AM_CONFIG_HEADER(config.h)

dnl ################################################################
dnl # Check for some standard stuff.
dnl ################################################################
AC_PROG_CC
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_PROG_LN_S
AC_PROG_INSTALL
AC_PROG_RANLIB

AC_C_CONST
AC_TYPE_SIZE_T
AC_EXEEXT
AC_HEADER_STDC

GLIB_REQUIRED_VER="2.2.2"
PKG_CHECK_MODULES(COMMON, \
	glib-2.0 >= $GLIB_REQUIRED_VER \
	gobject-2.0 >= $GLIB_REQUIRED_VER \
	gnet-2.0 >= 2.0.0)

AC_PATH_PROG([SDL_CONFIG], sdl-config)
AC_SUBST(COMMON_CFLAGS)
AC_SUBST(COMMON_LIBS)

if test -n "$SDL_CONFIG"; then
	SDL_CFLAGS="`$SDL_CONFIG --cflags`"
	SDL_LIBS="`$SDL_CONFIG --libs` -lSDL_image"

	old_CFLAGS="$CFLAGS"
	old_LDFLAGS="$LDFLAGS"
	CFLAGS="$SDL_CFLAGS"
	LDFLAGS="$SDL_LIBS"

	AC_CHECK_LIB([SDL_image], [IMG_Load],,
		AC_MSG_ERROR([Cannot find SDL_image on your system]))

	AC_CHECK_LIB([SDL_ttf], [TTF_Init],,
		AC_MSG_ERROR([Cannot find SDL_ttf on your system]))

	AC_CHECK_HEADERS(SDL_image.h SDL_ttf.h)

	CFLAGS="$old_CFLAGS"
	LDFLAGS="$old_LDFLAGS"
else
	AC_ERROR([You must have SDL installed to compile Tetringo.])
fi

AC_SUBST(SDL_CFLAGS)
AC_SUBST(SDL_LIBS)

GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
AC_SUBST(GLIB_GENMARSHAL)

AC_ARG_ENABLE([fullscreen],
              AC_HELP_STRING([--enable-fullscreen],
			                 [Run the game in fullscreen]),
			  [AC_DEFINE(USE_FULLSCREEN, 1, [Run in fullscreen mode])])

dnl # Use wall if we have GCC
if test "x$GCC" = "xyes"; then
    CFLAGS="$CFLAGS -Wall"
fi


dnl ################################################################
dnl # Output the Makefiles
dnl ################################################################
AC_CONFIG_FILES([
Makefile
data/Makefile
data/tetringo.desktop
libtetringo/Makefile
src/Makefile
tetringod/Makefile
])

AC_OUTPUT

echo
echo $PACKAGE v$VERSION
echo

echo prefix............... : $prefix

echo
echo "Now type make to compile"
echo "Then su to root and type: make install"
echo